102 lines
4.4 KiB
Bash
102 lines
4.4 KiB
Bash
. "$HOME/.zsh_aliases"
|
|
. "$HOME/.cargo/env"
|
|
|
|
# ZSH has a quirk where `preexec` is only run if a command is actually run (i.e
|
|
# pressing ENTER at an empty command line will not cause preexec to fire). This
|
|
# can cause timing issues, as a user who presses "ENTER" without running a command
|
|
# will see the time to the start of the last command, which may be very large.
|
|
|
|
# To fix this, we create STARSHIP_START_TIME upon preexec() firing, and destroy it
|
|
# after drawing the prompt. This ensures that the timing for one command is only
|
|
# ever drawn once (for the prompt immediately after it is run).
|
|
|
|
zmodload zsh/parameter # Needed to access jobstates variable for STARSHIP_JOBS_COUNT
|
|
|
|
# Defines a function `__starship_get_time` that sets the time since epoch in millis in STARSHIP_CAPTURED_TIME.
|
|
if [[ $ZSH_VERSION == ([1-4]*) ]]; then
|
|
# ZSH <= 5; Does not have a built-in variable so we will rely on Starship's inbuilt time function.
|
|
__starship_get_time() {
|
|
STARSHIP_CAPTURED_TIME=$(/home/oliver/.cargo/bin/starship time)
|
|
}
|
|
else
|
|
zmodload zsh/datetime
|
|
zmodload zsh/mathfunc
|
|
__starship_get_time() {
|
|
(( STARSHIP_CAPTURED_TIME = int(rint(EPOCHREALTIME * 1000)) ))
|
|
}
|
|
fi
|
|
|
|
# The two functions below follow the naming convention `prompt_<theme>_<hook>`
|
|
# for compatibility with Zsh's prompt system. See
|
|
# https://github.com/zsh-users/zsh/blob/2876c25a28b8052d6683027998cc118fc9b50157/Functions/Prompts/promptinit#L155
|
|
|
|
# Runs before each new command line.
|
|
prompt_starship_precmd() {
|
|
# Save the status, because subsequent commands in this function will change $?
|
|
STARSHIP_CMD_STATUS=$? STARSHIP_PIPE_STATUS=(${pipestatus[@]})
|
|
|
|
# Calculate duration if a command was executed
|
|
if (( ${+STARSHIP_START_TIME} )); then
|
|
__starship_get_time && (( STARSHIP_DURATION = STARSHIP_CAPTURED_TIME - STARSHIP_START_TIME ))
|
|
unset STARSHIP_START_TIME
|
|
# Drop status and duration otherwise
|
|
else
|
|
unset STARSHIP_DURATION STARSHIP_CMD_STATUS STARSHIP_PIPE_STATUS
|
|
fi
|
|
|
|
# Use length of jobstates array as number of jobs. Expansion fails inside
|
|
# quotes so we set it here and then use the value later on.
|
|
STARSHIP_JOBS_COUNT=${#jobstates}
|
|
}
|
|
|
|
# Runs after the user submits the command line, but before it is executed and
|
|
# only if there's an actual command to run
|
|
prompt_starship_preexec() {
|
|
__starship_get_time && STARSHIP_START_TIME=$STARSHIP_CAPTURED_TIME
|
|
}
|
|
|
|
# Add hook functions
|
|
autoload -Uz add-zsh-hook
|
|
add-zsh-hook precmd prompt_starship_precmd
|
|
add-zsh-hook preexec prompt_starship_preexec
|
|
|
|
# Set up a function to redraw the prompt if the user switches vi modes
|
|
starship_zle-keymap-select() {
|
|
zle reset-prompt
|
|
}
|
|
|
|
## Check for existing keymap-select widget.
|
|
# zle-keymap-select is a special widget so it'll be "user:fnName" or nothing. Let's get fnName only.
|
|
__starship_preserved_zle_keymap_select=${widgets[zle-keymap-select]#user:}
|
|
if [[ -z $__starship_preserved_zle_keymap_select ]]; then
|
|
zle -N zle-keymap-select starship_zle-keymap-select;
|
|
else
|
|
# Define a wrapper fn to call the original widget fn and then Starship's.
|
|
starship_zle-keymap-select-wrapped() {
|
|
$__starship_preserved_zle_keymap_select "$@";
|
|
starship_zle-keymap-select "$@";
|
|
}
|
|
zle -N zle-keymap-select starship_zle-keymap-select-wrapped;
|
|
fi
|
|
|
|
export STARSHIP_SHELL="zsh"
|
|
|
|
# Set up the session key that will be used to store logs
|
|
STARSHIP_SESSION_KEY="$RANDOM$RANDOM$RANDOM$RANDOM$RANDOM"; # Random generates a number b/w 0 - 32767
|
|
STARSHIP_SESSION_KEY="${STARSHIP_SESSION_KEY}0000000000000000" # Pad it to 16+ chars.
|
|
export STARSHIP_SESSION_KEY=${STARSHIP_SESSION_KEY:0:16}; # Trim to 16-digits if excess.
|
|
|
|
VIRTUAL_ENV_DISABLE_PROMPT=1
|
|
|
|
setopt promptsubst
|
|
|
|
PROMPT='$(/home/oliver/.cargo/bin/starship prompt --terminal-width="$COLUMNS" --keymap="${KEYMAP:-}" --status="$STARSHIP_CMD_STATUS" --pipestatus="${STARSHIP_PIPE_STATUS[*]}" --cmd-duration="${STARSHIP_DURATION:-}" --jobs="$STARSHIP_JOBS_COUNT")'
|
|
|
|
RPROMPT='$(/home/oliver/.cargo/bin/starship prompt --right --terminal-width="$COLUMNS" --keymap="${KEYMAP:-}" --status="$STARSHIP_CMD_STATUS" --pipestatus="${STARSHIP_PIPE_STATUS[*]}" --cmd-duration="${STARSHIP_DURATION:-}" --jobs="$STARSHIP_JOBS_COUNT")'
|
|
|
|
PROMPT2="$(/home/oliver/.cargo/bin/starship prompt --continuation)"
|
|
|
|
# Only load liquidprompt in interactive shells, not from a script or from scp
|
|
# echo $- | grep -q i 2>/dev/null && . /usr/share/liquidprompt/liquidprompt
|
|
|